@echo off
chcp 65001 >nul
title KLauncher - proverka seti
setlocal enabledelayedexpansion

echo ================================================
echo    KLauncher - proverka setevogo soedineniya
echo ================================================
echo.
echo Proveryayu dostupnost serverov (~20 sek)...
echo.

set FAIL=0
where curl >nul 2>&1 && (set HAVE_CURL=1) || (set HAVE_CURL=0)

call :http "KLauncher API              " https://api.klaun.ch
call :http "KLauncher zagruzki (repos) " https://repos.klaun.ch
call :http "Mojang: spisok versiy      " https://piston-meta.mojang.com/mc/game/version_manifest.json
call :http "Mojang: fayly igry         " https://piston-data.mojang.com
call :http "Mojang: biblioteki         " https://libraries.minecraft.net
call :http "Mojang: assety             " https://resources.download.minecraft.net

echo.
echo ------------------------------------------------
if "!FAIL!"=="0" (
  echo   ITOG: vse servery DOSTUPNY.
  echo.
  echo   Esli versii/sborki vsyo ravno ne gruzyatsya:
  echo    - perezapustite launcher;
  echo    - perezagruzite router;
  echo    - vyklyuchite programmy, menyayushchie internet-soedinenie.
) else (
  echo   ITOG: nedostupno serverov: !FAIL!  ^(stroki [FAIL] vyshe^)
  echo.
  echo   Chto poprobovat po ocheredi:
  echo    1. Perezagruzit router.
  echo    2. Smenit DNS na 1.1.1.1 ili 8.8.8.8.
  echo    3. Vyklyuchit programmy, vmeshivayushchiesya v soedinenie.
  echo    4. Vremenno otklyuchit antivirus/fayrvol.
  echo.
  echo   Sdelayte skrinshot etogo okna i prishlite v podderzhku.
)
echo ------------------------------------------------
echo.
pause
exit /b

:http
set "NAME=%~1"
set "URL=%~2"
set "CODE=000"
if "!HAVE_CURL!"=="1" (
  for /f "delims=" %%c in ('curl -s -o nul -m 10 -w "%%{http_code}" "!URL!" 2^>nul') do set "CODE=%%c"
) else (
  for /f "delims=" %%c in ('powershell -NoProfile -Command "try{(Invoke-WebRequest -UseBasicParsing -TimeoutSec 10 -Uri '!URL!').StatusCode}catch{if($_.Exception.Response){[int]$_.Exception.Response.StatusCode}else{'000'}}" 2^>nul') do set "CODE=%%c"
)
if "!CODE!"=="000" (
  echo   [FAIL] !NAME! - net soedineniya
  set /a FAIL+=1
) else (
  echo   [ OK ] !NAME! - HTTP !CODE!
)
exit /b